-------------------------------------------------------------------------------
-- Program      : ARD Reset Username & Password
-- Purpose      : Automate changing the username and password for connections
-- Based upon   : An AppleScript by Richard Glaser & James Reynolds
-- Revised      : 2005/09/15 <hkr> Initial version
--------------------------------------------------------------------------------

tell application "Remote Desktop"
    set window_names to the name of (every window whose visible is true and name ends with "Info")
end tell

if window_names = {} then
    display dialog "You don't have any info windows open." buttons {"Ooops"} default button 1
    return
end if

set ARD_user to the text returned of (display dialog "ARD Login:" default answer "username" with title "ARD Login")
set ARD_password to the text returned of (display dialog "ARD Password:" default answer "password" with title "ARD Password" with hidden answer)

tell application "System Events"
    tell process "Remote Desktop"
        repeat with this_window_name in window_names
            click button "Edit" of window this_window_name
            set value of text field 2 of group 1 of window this_window_name to ARD_user
            set value of text field 3 of group 1 of window this_window_name to ARD_password
            click button "Done" of window this_window_name
            click button 1 of window this_window_name
        end repeat
    end tell
end tell